[VBA]If문과 Select문의 비교

프로그래밍의 가장 기본 중의 하나가 If문에 의한 실행의 분기일 것이다.

단순한 분기에서부터 다중 분기까지 가능하다.

<문제>

성적 점수에 따라 평점(A, B, C, D, F 등으로 표시되는 것. 학점하고 구분)을 반환하는 함수를 작성하라.

1) If문을 이용한 함수 1

Public Function GetGrade1(ByVal AverageScore As Single) As String
  If AverageScore >= 95 Then
    GetGrade1 = "A+"
  ElseIf AverageScore >= 90 And AverageScore < 95 Then
    GetGrade1 = "A0"
  ElseIf AverageScore >= 85 And AverageScore < 90 Then
    GetGrade1 = "B+"
  ElseIf AverageScore >= 80 And AverageScore < 85 Then
    GetGrade1 = "B0"
  ElseIf AverageScore >= 75 And AverageScore < 80 Then
    GetGrade1 = "C+"
  ElseIf AverageScore >= 70 And AverageScore < 75 Then
    GetGrade1 = "C0"
  Else
    GetGrade1 = "F"
  End If
End Function

조건이 굉장히 복잡하게 보이지만, 계산 논리를 한번에 알아볼 수 있다. 이렇게 다중 분기하는 경우 다음과 같이 Select문을 생각해 볼 수 있다.

2)Select문을 이용한 함수

Public Function GetGrade2(ByVal AverageScore As Double) As String
  Select Case AverageScore
    Case 95 To 100
      GetGrade2 = "A+"
    Case 90 To 94
      GetGrade2 = "A0"
    Case 85 To 89
      GetGrade2 = "B+"
    Case 80 To 84
      GetGrade2 = "B0"
    Case 75 To 79
      GetGrade2 = "C+"
    Case 70 To 74
      GetGrade2 = "C0"
    Case Else
      GetGrade2 = "F"
  End Select
End Function

이 함수는 심각한 문제를 안고 있다. 즉, 85.5와 같은 점수에 대해서는 “F”를 줄 수 있기 때문이다. Case 간에 비어있는 범위가 생길 수 있다는 점에서 유의해야 한다.

3)다시 If문을 이용한 함수

처음 If문을 간결하게 다시 작성하면 다음과 같이 할 수 있다. 여기서 중요하게 볼 것은 처음 조건문은 그 다음 조건문의 필터 역할을 한다는 것이다. 예를들어 85.5점은 처음 조건문부터해서 두번째 조건문까지 만족하지 않는다. 그러나, 세번째 조건문에서는 통과하여 평점을 받게 된다. 즉, 세번째 조건문에 ’90보다 작다’는 필터가 두번째의 조건문을 통해서 만들어진 것이다.

Function GetGrade3(ByVal 점수 As Double) As String
  Dim grade As String = ""
  If 점수 >= 95 Then
    grade = "A+"
  ElseIf 점수 >= 90 Then
    grade = "A"
  ElseIf 점수 >= 85 Then
    grade = "B+"
  ElseIf 점수 >= 80 Then
    grade = "B"
  ElseIf 점수 >= 75 Then
    grade = "C+"
  ElseIf 점수 >= 70 Then
    grade = "C"
  ElseIf 점수 >= 65 Then
    grade = "D+"
  ElseIf 점수 >= 60 Then
    grade = "D"
  Else
    grade = "F"
  End If
  GetGrade3 = grade
End Function

주의사항 : 제대로 된 필터 기능을 사용하고자 한다면, 점수가 고득점부터 저득점으로 내려오든, 저득점에서 고득점으로 올라가든, 일정한 순서로 조건문을 배열해야 한다는 점이다.

정령 Select문으로는 해결할 수 없는가?
이것을 Select문으로 바꾸면 다음과 같이 될 것이다.

4) 다시 Select문을 이용한 함수

Is라는 키워드를 사용하면 다음과 같이 작성할 수 있다.

Function GetGrade4(ByVal 점수 As Double) As String
  Dim grade As String = ""
  Select Case 점수
    Case Is >= 95
      grade = "A+"
    Case Is >= 90
      grade = "A"
    Case Is >= 85
      grade = "B+"
    Case Is >= 80
      grade = "B"
    Case Is >= 75
      grade = "C+"
    Case Is >= 70
      grade = "C"
    Case Is >= 65
      grade = "D+"
    Case Is >= 60
      grade = "D"
    Case Else
      grade = "F"
  End Select
  GetGrade4 = grade
End Function

이 방법도 Case 점수가 일정한 순서로 배치되어 가능하다는 점을 유의해야 한다.

Print Friendly, PDF & Email